woody/Gen4_R-Car_Trace32
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
d411edd9b47003e0a9ef98de9aef8259ddea419d
Gen4_R-Car_Trace32/2_Trunk/demo/arm/flash/mkv30.cmm
woody d411edd9b4 add Trace32 File
2025-10-14 09:52:32 +09:00

277 lines
7.5 KiB
Plaintext
Raw Blame History

; --------------------------------------------------------------------------------
; @Title: Generic script for Freescale MKV31 internal flash
;
; @Description:
; Example for flash declaration of Freescale MKV31 internal flash.
;
; Script arguments:
;
; DO mkv30 [PREPAREONLY] [CPU=<cpu>] [MASSERASE]
;
; PREPAREONLY only declares flash but does not execute flash programming
;
; CPU=<cpu> selects CPU derivative <cpu>
;
; MASSERASE forces mass erase of device before establishing debug connection
;
; Example:
;
; DO ~~/demo/arm/flash/mkv30 CPU=MKV31F512VLL12 PREPAREONLY
;
; List of MKV31 derivatives and their configuration:
;
; CPU-Type ProgFlash FlexNVM EEPROM RamSize
; [Byte] [Byte] [Byte] [Byte]
; --------------------------------------------------------------------------------
; MKV30F128VFM10 128KB - - 16KB
; MKV30F128VLF10 128KB - - 16KB
; MKV30F128VLF10P 128KB - - 16KB
; MKV30F128VLH10 128KB - - 16KB
; MKV31F128VLH10 128KB - - 24KB
; MKV31F128VLH10P 128KB - - 24KB
; MKV31F128VLL10 128KB - - 24KB
; MKV31F256VLL12 256KB - - 48KB
; MKV31F256VLH12 256KB - - 48KB
; MKV31F256VLH12P 256KB - - 48KB
; MKV31F256VLH12R 256KB - - 48KB
; MKV31F512VLL12 512KB - - 96KB
; MKV31F512VLL12P 512KB - - 96KB
; MKV31F512VLH12 512KB - - 96KB
; MKV31F512VLH12R 512KB - - 96KB
;
; Flash Configuration Field:
;
; Byte address Width Description
; --------------------------------------------------------------------------------
; 0x0400--0x0407 8 Backdoor Comparison Key.
; 0x0408--0x040B 4 Program flash protection bytes (FPROT0-3).
; 0x040F 1 Program flash only devices: Reserved
; FlexNVM devices: Data flash protection byte
; (FDPROT).
; 0x040E 1 Program flash only devices: Reserved
; FlexNVM devices: EEPROM protection byte
; (FEPROT).
; 0x040D 1 Flash nonvolatile option byte (FOPT).
; 0x040C 1 Flash security byte (FSEC).
;
; @Chip: MKV3*
; @Author: FLC
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Rev: 10516 $
; $Id: mkv30.cmm 10516 2022-02-02 11:39:30Z bschroefel $
;
LOCAL &parameters
ENTRY %LINE &parameters
LOCAL &param_prepareonly &param_masserase
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
&param_masserase=(STRing.SCAN(STRing.UPpeR("&parameters"),"MASSERASE",0)!=-1)
LOCAL &param_cpu
&param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")
; ------------------------------------------------------------------------------
; Setup CPU
IF (SYStem.MODE()<5)||&param_masserase
(
SYStem.RESet
IF "&param_cpu"!=""
SYStem.CPU &param_cpu
IF !CPUIS(MKV31*)
SYStem.CPU MKV3*
IF CABLE.TWOWIRE()
(
SYStem.CONFIG.DEBUGPORTTYPE SWD
)
ELSE
(
SYStem.CONFIG.DEBUGPORTTYPE JTAG
)
IF &param_masserase
GOSUB MassErase
ON.ERROR GOSUB Unsecure
SYStem.Up
ON.ERROR
)
; Unsecure device
IF (Data.Long(EDBG:0x40000100)&0x04)==0x04
GOSUB Unsecure
; Disable watchdog
ON.ERROR GOSUB Unsecure
GOSUB DisableWatchdog
ON.ERROR
; ------------------------------------------------------------------------------
; Flash declaration
FLASH.RESet
GOSUB FlashDeclaration
; Flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
ENDDO PREPAREDONE
; ------------------------------------------------------------------------------
; Flash programming example
DIALOG.YESNO "Program flash memory?"
LOCAL &progflash
ENTRY &progflash
IF &progflash
(
FLASH.ReProgram.ALL /Erase
Data.LOAD.auto *
FLASH.ReProgram.off
; Reset device
SYStem.Down
SYStem.Up
; Disable watchdog
GOSUB DisableWatchdog
)
ENDDO
; --------------------------------------------------------------------------------
; Disable watchdog
DisableWatchdog:
LOCAL &tmp1 &tmp2
&tmp1=Data.Long(ST:0x20000000)
&tmp2=Data.Long(ST:0x20000004)
; The watchdog has a restrictive timing. It has to be configured and unlocked within a peripod
; of 20+256 cycles. Therefor the unlock sequence need to be done by a small target program.
Data.Assemble ST:0x20000000 strh r1,[r0] ;SD:0x4005200E = 0xC520 (Key 1)
Data.Assemble , strh r2,[r0] ;SD:0x4005200E = 0xD928 (Key 2)
Data.Assemble , strh r4,[r3] ;SD:0x40052000 = 0x0000 (Config register)
Data.Assemble , bkpt #0
Register.Set PC 0x20000000
Register.Set SP 0x20001000
Register.Set R0 0x4005200E
Register.Set R1 0xC520
Register.Set R2 0xD928
Register.Set R3 0x40052000
Register.Set R4 0x0
Go.direct
WAIT !STATE.RUN()
Data.Set ST:0x20000000 %Long &tmp1
Data.Set ST:0x20000004 %Long &tmp2
RETURN
; --------------------------------------------------------------------------------
; Try to unsecure a secured device
Unsecure:
; Print security state information
SYStem.Mode.Prepare
PRINT "MDM-AP Status Register is 0x" Data.Long(EDBG:0x40000100)
DIALOG.YESNO "Execute mass erase to unsecure chip?"
LOCAL &masserase
ENTRY &masserase
IF &masserase
(
ON.ERROR DEFault
; Unsecure device
SYStem.Down
FLASH.UNSECUREerase
SYStem.Mode.Prepare
IF (Data.Long(EDBG:0x40000100)&0x04)==0x04
(
PRINT %ERROR "Unsecure failed, MDM-AP Status Register is 0x" Data.Long(EDBG:0x40000100)
SYStem.Down
ENDDO
)
)
ELSE
ENDDO
SYStem.Up
; Disable watchdog
GOSUB DisableWatchdog
RETURN
; --------------------------------------------------------------------------------
; Try to mass erase the device
MassErase:
; Mass erase device by unsecure command
SYStem.Down
FLASH.UNSECUREerase
SYStem.Mode.Prepare
IF (Data.Long(EDBG:0x40000100)&0x24)!=0x20
(
PRINT %ERROR "Mass erase failed, MDM-AP Status Register is 0x" Data.Long(EDBG:0x40000100)
SYStem.Down
ENDDO
)
RETURN
; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU
FlashDeclaration:
LOCAL &PFlashSize
LOCAL &PSectorSize
LOCAL &flashdriver
&flashdriver="t.b.d."
; Setup configuration values
IF (CPUIS("MKV31F128*")||CPUIS("MKV30F128*"))
(
&PFlashSize=0x20000
&PSectorSize=0x800
&flashdriver="ftfl4n.bin"
)
ELSE IF CPUIS("MKV31F256*")
(
&PFlashSize=0x40000
&PSectorSize=0x800
&flashdriver="ftfl4n.bin"
)
ELSE IF CPUIS("MKV31F512*")
(
&PFlashSize=0x80000
&PSectorSize=0x800
&flashdriver="ftfl4n.bin"
)
ELSE
(
PRINT %ERROR "FLASH size of CPU type is not supported by the script"
ENDDO
)
; Program Flash
IF &PFlashSize>=0x20000
FLASH.Create 1. 0x00000000--0x0001FFFF &PSectorSize TARGET Long
IF &PFlashSize>=0x40000
FLASH.Create 1. 0x00020000--0x0003FFFF &PSectorSize TARGET Long
IF &PFlashSize>=0x80000
FLASH.Create 2. 0x00040000--0x0007FFFF &PSectorSize TARGET Long
FLASH.TARGET 0x1FFFF000 0x20000000 &PSectorSize ~~/demo/arm/flash/long/&flashdriver
RETURN
Reference in New Issue View Git Blame Copy Permalink