126 lines
3.6 KiB
Plaintext
126 lines
3.6 KiB
Plaintext
; --------------------------------------------------------------------------------
|
|
; @Title: NXP QorIQ LS1046A RDB QSPI FLASH Programming Script
|
|
; @Description:
|
|
; Script to program S25FS512S (Cypress) attached to CS#0 of a LS1046A from NXP.
|
|
;
|
|
; Internal SRAM: 0x10000000
|
|
; QuadSPI(controller) Base: 0x1550000
|
|
; FLASH BASE ADDRESS(Qspi mapped): 0x40000000
|
|
;
|
|
; Prerequisites:
|
|
; * Connect Debug Cable/Combiprobe to J22
|
|
; * Set SW5[1..8]+SW4[1]==RCW-SRC to
|
|
; QSPI 0y001000100
|
|
; * Set SW3[3..5]==QSPI_MAP to select the QSPI bank
|
|
; e.g. 0y000
|
|
;
|
|
; @Author: jjeong
|
|
; @Chip: LS1046A
|
|
; @Board: LS1046A-RDB
|
|
; @Keywords: S25FS512S Flash SPI QuadSPI
|
|
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
|
|
; --------------------------------------------------------------------------------
|
|
; $Id: ls1046-spi.cmm 11732 2023-01-16 08:40:56Z bschroefel $
|
|
LOCAL ¶meters &QSPI_BASE ¶m_prepareonly
|
|
ENTRY %LINE ¶meters
|
|
|
|
¶m_prepareonly=(STRing.SCAN(STRing.UPpeR("¶meters"),"PREPAREONLY",0)!=-1)
|
|
&QSPI_BASE=0x1550000
|
|
|
|
RESet
|
|
SYStem.RESet
|
|
SYStem.CPU LS1046A
|
|
SYStem.MemAccess DAP
|
|
SYStem.Option TRST OFF
|
|
CORE.ASSIGN 1.
|
|
Trace.DISable
|
|
SYStem.JtagClock CTCK 10MHz
|
|
MAP.BE &QSPI_BASE++0xFFFF
|
|
SYStem.Up
|
|
|
|
; We should now have access to the QSPI & SD card pins
|
|
Data.Assemble 0x10000000 b $-0x0
|
|
Register.Set PC 0x10000000
|
|
Data.Set AD:0x1550000 %BE %Long 0xF0000 ; QSPI_MCR[END_CFG], 64BE
|
|
|
|
GOSUB READ_ID_TEST "&QSPI_BASE"
|
|
|
|
; 3byte read, mapped memory address 0x40000000
|
|
// D.S MD:0x1550310 %BE %Long (0x08180400|0x3)
|
|
|
|
; 4byte read for spansion flash memory
|
|
Data.Set AD:0x1550310 %BE %Long (0x08200400|0x13)
|
|
Data.Set AD:0x1550314 %BE %Long 0x24001C08
|
|
|
|
; Flash declaration
|
|
(
|
|
PRIVATE &pdd
|
|
|
|
&pdd=OS.PresentDemoDirectory()
|
|
|
|
FLASH.RESet
|
|
FLASH.Create 0x40000000++0x01ffffff 0x40000 target byte
|
|
FLASH.TARGET 0x10000000 0x10002000 0x1000 &pdd/flash/byte/snor_ls1000.bin
|
|
)
|
|
|
|
; Flash script ends here if called with parameter PREPAREONLY
|
|
IF ¶m_prepareonly
|
|
ENDDO PREPAREDONE
|
|
|
|
; --------------------------------------------------------------------------------
|
|
; Flash programming example
|
|
; -------------------------------------------------------------------------------
|
|
(
|
|
PRIVATE &progflash
|
|
|
|
DIALOG.YESNO "Program flash memory?"
|
|
ENTRY &progflash
|
|
|
|
IF &progflash
|
|
(
|
|
FLASH.ReProgram.ALL
|
|
Data.LOAD.auto *
|
|
;Data.LOAD.Binary * 0x40000000
|
|
FLASH.ReProgram.off
|
|
)
|
|
)
|
|
|
|
ENDDO
|
|
|
|
; --------------------------------------------------------------------------------
|
|
; Subroutines
|
|
|
|
READ_ID_TEST:
|
|
(
|
|
PRIVATE &QSPI_BASE &temp
|
|
PARAMETERS &QSPI_BASE
|
|
|
|
PRINT "READ_ID_TEST..."
|
|
&temp=Data.Long(AD:&QSPI_BASE)
|
|
Data.Set AD:&QSPI_BASE %Long %BE (&temp|0x0c00) ; Clear Tx/Rx buffer
|
|
|
|
Data.Set AD:(&QSPI_BASE+0x300) %Long %BE 0x5AF05AF0 ; LUTKEY
|
|
Data.Set AD:(&QSPI_BASE+0x304) %Long %BE 0x2 ; LCKCR
|
|
|
|
//SEQID 5
|
|
Data.Set AD:(&QSPI_BASE+0x360) %Long %BE 0x1c04049f ; LUT0, SEQID0
|
|
Data.Set AD:(&QSPI_BASE+0x364) %Long %BE 0x0
|
|
Data.Set AD:(&QSPI_BASE+0x368) %Long %BE 0x0
|
|
Data.Set AD:(&QSPI_BASE+0x36C) %Long %BE 0x0
|
|
|
|
Data.Set AD:(&QSPI_BASE+0x100) %Long %BE 0x40000000 ; SFAR , FLASH BASE ADDRESS
|
|
|
|
// assert Read id command
|
|
Data.Set AD:(&QSPI_BASE+0x008) %Long %BE (5.<<24.) ; (5.<<24.)
|
|
WAIT 100.ms
|
|
|
|
&temp=Data.Long(AD:&QSPI_BASE)
|
|
Data.Set AD:&QSPI_BASE %Long %BE (&temp|0x0800) //clear Tx buffer
|
|
|
|
PRINT "1st 0x" Data.Long(AD:&QSPI_BASE+0x200)>>24. " (Manufacturer)"
|
|
PRINT "2nd 0x" (Data.Long(AD:&QSPI_BASE+0x200)>>16.)&0xFF " (Device ID)"
|
|
PRINT "3rd 0x" (Data.Long(AD:&QSPI_BASE+0x200)>>8.)&0xFF
|
|
PRINT "4th 0x" Data.Long(AD:&QSPI_BASE+0x200)&0xFF
|
|
RETURN
|
|
)
|