; --------------------------------------------------------------------------------
; @Title: Start-up script for TCC897x-CM4
; @Description:
;   While the CPU selection is basically sufficient for debugging the Cortex-A7
;   cores, you need to make further settings to reach the Cortex-M4.
;   Once the Cortex-M4 is selected (when you run this script), you must perform a
;   power-on reset before you can debug the Cortex-A7 cores.
; @Keywords: ARM, Cortex-M4
; @Author: PEG
; @Board: TCC8971 EVB
; @Chip: TCC8971
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: tcc897x-cm4.cmm 19230 2022-04-14 08:50:33Z pegold $


WinCLEAR

; --------------------------------------------------------------------------------
; initialize and start the debugger
RESet
SYStem.CPU TCC8971-CM4
GOSUB ConfigureDebugPortAndMore
SYStem.Up

ENDDO

ConfigureDebugPortAndMore:
(
  ; configure debug port for TCC897x-CM4
  SYStem.CONFIG AHBACCESSPORT 2
  SYStem.MODE Prepare
  IF Data.Long(EAHB:0x0)==0 ; check if TCC897x-CM4 is selected
  (
    SYStem.CONFIG AHBACCESSPORT 0
    RETURN
  )
  ELSE
  (
    ON ERROR CONTinue           ; ignore error because communication will break down
    Data.Set EAHB:0x4 %Long 0x1 ; JTAG_SEL, configure JTAG interface for TCC897x-CM4
    SYStem.MODE Down            ; communication will break down on the command before
    ON ERROR DEFault            ; normal error handling

    SYStem.CONFIG AHBACCESSPORT 0
    RETURN
  )
)