; --------------------------------------------------------------------------------
; @Title: Script for programming of GigaDevice GD32L233 internal flash
;
; @Description: 
; Script arguments:
;
;  do gd32l233 [PREPAREONLY] [CPU=<cpu>]
;
;   PREPAREONLY only declares flash but does not execute flash programming example
;
;   CPU=<cpu> selects CPU derivative <cpu>
;
; List of GD32L233 derivatives and their configuration:
;
;   CPU-Type      Flash size   SRAM size
;                   (kByte)     (kByte)
; --------------------------------------------------------------------------------
;   GD32L233x8        64.          16.
;   GD32L233xB       128.          24.
;   GD32L233xC       256.          32.
; ------------------------------------------------------- -------------------------
;
; Flash base address is 0x08000000
; SRAM base address is  0x20000000
;
; @Author: ALI
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; @Chip: GD32L233*
; --------------------------------------------------------------------------------
; $Rev: 11230 $
; $Id: gd32l233.cmm 11230 2022-08-26 10:07:00Z alintner $

PRIVATE  &parameters
ENTRY %LINE &parameters

PRIVATE  &param_prepareonly
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)

PRIVATE  &param_cpu
&param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")

PRIVATE &param_dualport
&param_dualport=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"DUALPORT=","1")

; ------------------------------------------------------------------------------
; CPU setup

IF SYStem.MODE()<5
(
  SYStem.RESet
  IF "&param_cpu"!=""
    SYStem.CPU &param_cpu
  IF !CPUIS(GD32L233*)
    SYStem.CPU GD32L233*

    IF CABLE.TWOWIRE()
      SYStem.CONFIG.DEBUGPORTTYPE SWD

  SYStem.Up
)

; ------------------------------------------------------------------------------
; Flash declaration

FLASH.RESet

PRIVATE &FlashSize
GOSUB FlashDeclaration &param_dualport
ENTRY &FlashSize

; Flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
  ENDDO PREPAREDONE

; ------------------------------------------------------------------------------
; Flash programming example

DIALOG.YESNO "Program flash memory?"
PRIVATE  &progflash
ENTRY &progflash

IF &progflash 
(
  FLASH.ReProgram 0x08000000++(&FlashSize-1) /Erase
  Data.LOAD.auto *
  FLASH.ReProgram off

  ; Reset device
  SYStem.Down
  SYStem.Up
)

ENDDO


; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU 

FlashDeclaration:
(
  PRIVATE  &FlashSize &DualPort
  ENTRY &DualPort

  IF CPUIS("GD32L233?8*")
  (
    &FlashSize=0x10000 ; 64 kByte
  )
  ELSE IF CPUIS("GD32L233?B*")
  (
    &FlashSize=0x20000 ; 128 kByte
  )
  ELSE IF CPUIS("GD32L233?C*")
  (
    &FlashSize=0x40000 ; 256 kByte
  )
  ELSE
  (
    PRINT %ERROR "FLASH size of CPU type is unknown"
    ENDDO
  )

  ; Program memory flash
  IF &FlashSize==0x8000 ; 32 kByte
    FLASH.Create 1. 0x08000000--0x08007FFF  0x400 TARGET Long
  ELSE IF &FlashSize==0x10000 ; 64 kByte
    FLASH.Create 1. 0x08000000--0x0800FFFF  0x400 TARGET Long
  ELSE IF &FlashSize==0x20000 ; 128 kByte
    FLASH.Create 1. 0x08000000--0x0801FFFF  0x800 TARGET Long
  ELSE IF &FlashSize==0x40000 ; 256 kByte
    FLASH.Create 1. 0x08000000--0x0803FFFF  0x1000 TARGET Long

  ; For Main Flash memory boot mode flash memory is aliased to address 0x0
  ; Because SYSCFG_MEMRMP:MEM_MODE[1:0] is not indicating active memory remap
  ; we are comparing flash reset vector against reset vector at alias address
  Data.ComPare 0x0--0x7 0x08000000
  IF !FOUND()
    FLASH.CreateALIAS 0x00000000++(&FlashSize-1) 0x08000000

  IF "&DualPort"=="0"
  (
    FLASH.TARGET 0x20000000 0x20001000 0x400 ~~/demo/arm/flash/long/gd32f3x0.bin
  )
  ELSE
  (
    FLASH.TARGET 0x20000000 0x20001000 0x400 ~~/demo/arm/flash/long/gd32f3x0.bin /DualPort
  )

  RETURN &FlashSize
)