; --------------------------------------------------------------------------------
; @Title: Executes a PRACTICE command via INTERCOM on all connected instances
; @Description:
;   This script executed a PRACTICE command, which is passed as parameter,
;   to all PowerView instances which are connected to the same debug module.
;   Note: Deprecated since build 95187, use built-in command 
;   InterCom.execute ALL <command>
;
;   Usage:
;   DO ~~/demo/practice/intercom/execute_all.cmm <PRACTICE command>
;
;   Example:
;   DO ~~/demo/practice/intercom/execute_all.cmm SYStem.Mode.Attach
;
; @Author: REI
; @Copyright: (C) 1989-2021 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: execute_all.cmm 17068 2021-01-28 18:36:58Z rweiss $

LOCAL &cmd
ENTRY %LINE &cmd

IF VERSION.BUILD()>=95187.
(
  ;use built-in feature
  InterCom.execute ALL &cmd
  ENDDO
)

LOCAL &index &count &podport &icport
&index=0
&count=InterCom.PODPORTNUMBER()

WHILE &index<&count
(
  &podport=InterCom.PODPORT(&index)
  &icport=FORMAT.Decimal(1.,&podport)
  IF &podport!=InterCom.PORT()
    InterCom.execute &icport &cmd
  ELSE
    &cmd
  &index=&index+1
)
ENDDO