; --------------------------------------------------------------------------------
; @Title: Additional eCos Menues
; @Description: -
; @Author: DIE
; @Copyright: (c) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: ecos.m 7861 2022-07-29 13:45:42Z amerkle $

NAME "TASK.ECOS"

IF !MENU.EXIST("TASK.ECOS")
(
add
menu
(
  popup "ECOS"
  (
    if y.exist(T32OUT)
    (
      menuitem "&eCos Terminal" "TERM T32OUT T32IN"
      separator
    )
    default
    menuitem "Display &Threads"    "TASK.THRead"
    menuitem "Display &Scheduler"  "TASK.SCHEDuler"
    separator
    popup "&Stack Coverage"
    (
      menuitem "List Stacks"           "TASK.STacK"
      menuitem "Add Task to Cov"       "TASK.STacK.ADD"
      menuitem "Remove Task from Cov"  "TASK.STacK.ReMove"
      menuitem "Reset Coverage"
      (
        PRIVATE &yes
        DIALOG.YESNO "Overwrite unused stack space" "with stack fill pattern?"
        ENTRY &yes
        IF !&yes
          ENDDO
        TASK.STacK.Init
      )
    )
  )
  popup "Trace"
  (
    popup "[:alist]List"
    (
      separator
      menuitem "&Task Switches"     "Trace.List List.TASK"
      menuitem "&Default and Tasks" "Trace.List List.TASK DEFault"
    )
  )
  popup "Perf"
  (
    separator
    popup "&Task Runtime"
    (
      menuitem "&Prepare"
      (
        if t.method.analyzer()
        (
          Analyzer.AutoInit on
        )
        Break.Delete /Alpha
        Break.Set task.config(magic)++(task.config(magicsize)-1) /Alpha
      )
      menuitem "[:perf]Show &Numerical"   "Trace.STATistic.TASK"
      menuitem "[:achart]Show as &Timing" "Trace.CHART.TASK"
      menuitem "[:achart]Tracking with Trace &List"
      (
        Trace.List List.TASK DEFault /Track
        Trace.CHART.TASK /Track
      )
    )
    popup "&Task Function Runtime"
    (
      menuitem "&Prepare"
      (
        if t.method.analyzer()
        (
          Analyzer.AutoInit on
          Analyzer.STATistic.PreFetch on
        )
        Break.Delete /Alpha /Beta /Charly
        Break.SetFunc
        Break.Set task.config(magic)++(task.config(magicsize)-1) /Alpha
      )
      menuitem "[:perf]Show &Numerical"     "Trace.STATistic.TASKFUNC"
      menuitem "[:perf]Show as &Tree"       "Trace.STATistic.TASKTREE"
      menuitem "[:perf]Show &Detailed Tree" "Trace.STATistic.TASKTREE ALL"
      menuitem "[:achart]Show as &Timing"   "Trace.CHART.TASKFUNC"
      menuitem "[:alist]Show N&esting"      "Trace.List List.TASK FUNC TI.FUNC"
    )
    popup "Task &Status"
    (
      menuitem "&Prepare"
      (
        if t.method.analyzer()
        (
          Analyzer.AutoInit on
        )
        Break.Delete /Alpha
        Break.Set task.config(magic)++(task.config(magicsize)-1) /Alpha
        TASK.TASKState
      )
      menuitem "[:perf]Show &Numerical"   "Trace.STATistic.TASKSTATE"
      menuitem "[:achart]Show as &Timing" "Trace.CHART.TASKSTATE"
      menuitem "[:achart]Tracking with Trace &List"
      (
        Trace.List List.TASK DEFault /Track
        Trace.CHART.TASKSTATE /Track
      )
    )
  )
  popup "&Help"
  (
     menuitem "eCos RTOS Debugger Manual" "HELP __RTOS_ECOS_"
  )
)


menu "task.thr"
(
  default
  menuitem "Display Detailed"
  (
    PRIVATE &nAddress
    &nAddress=ADDRESS.OFFSET(TRACK.ADDRESS())
    TASK.THRead &nAddress
  )
  menuitem "Display Object"
  (
    PRIVATE &nAddress
    &nAddress=ADDRESS.OFFSET(TRACK.ADDRESS())
    Var.View %m %in (Cyg_Thread*)&nAddress
  )
  if (task.config(context)!=0)
  (
    menuitem "Display Stack Frame"
    (
      PRIVATE &nAddress
      &nAddress=ADDRESS.OFFSET(TRACK.ADDRESS())
      Frame /Locals /Caller /TASK &nAddress
    )
    menuitem "Switch Context"
    (
      PRIVATE &nAddress
      &nAddress=ADDRESS.OFFSET(TRACK.ADDRESS())
      Register.TASK &nAddress
    )
  )
  separator
  menuitem "Add to Stack Cov"
  (
    PRIVATE &nAddress
    &nAddress=ADDRESS.OFFSET(TRACK.ADDRESS())
    TASK.STacK.ADD &nAddress
  )
  menuitem "Rm from Stack Cov"
  (
    PRIVATE &nAddress
    &nAddress=ADDRESS.OFFSET(TRACK.ADDRESS())
    TASK.STacK.RM &nAddress
  )
  separator
  menuitem "Dump thread entry"
  (
    PRIVATE &pAddress
    &pAddress=TRACK.ADDRESS()
    Data.dump &pAddress /Long /DIALOG
  )
)
)