; --------------------------------------------------------------------------------
; @Title: Example for flash declaration of Toshiba TXZ3A+ Series internal flash. 
;
; @Description:
; Script arguments:
;   DO tmpm3hxf10 [PREPAREONLY] [CPU=<cpu>] [DUALPORT=<0|1>]
;     PREPAREONLY    only declares flash but does not execute flash programming
;     CPU=<cpu>      selects CPU derivative <cpu>
;     DUALPORT=<0|1> use dual port memory access, default 0
;
; Example:
;   DO ~~/demo/arm/flash/tmpm3hxf10 PREPAREONLY CPU=TMPM3HPF10BFG DUALPORT=1
;
; List of TXZ3A+ Series derivatives and their configuration:
;      CPU-Type         Code Flash    RamSize    Data Flash
;                        [Kbyte]      [Kbyte]     [Kbyte]
; --------------------------------------------------------------------------------
;   TMPM3HQF10BFG        0x100000     0x20000      0x8000
;   TMPM3HPF10BFG        0x100000     0x20000      0x8000
;   TMPM3HPF10BDFG       0x100000     0x20000      0x8000
;   TMPM3HNF10BFG        0x100000     0x20000      0x8000
;   TPM3HNFDBFG          0x80000      0x20000      0x8000
;   TMPM3HNF10BDFG       0x100000     0x20000      0x8000
;   TMPM3HMF10BFG        0x100000     0x20000      0x8000
;   TMPM3HLF10BUG        0x100000     0x20000      0x8000
;
; The internal flash is located at 0x00000000 (User boot mode)
;                               or 0x5E100000 (Single boot mode)
; The internal RAM is located at   0x20000000
; The BOOTROM is located at        0x00000000 (Single boot mode)
;
; @Author: MDT
; @Copyright: (C) 1989-2024 Lauterbach GmbH, licensed for use with TRACE32(R) only
; @Chip: TMPM3H*F10*
; --------------------------------------------------------------------------------
; $Rev: 13346 $
; $Id: tmpm3hxf10.cmm 13346 2024-04-18 13:44:02Z mtrabelsi $

  LOCAL &parameters
  ENTRY %LINE &parameters

  LOCAL &param_prepareonly
  &param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
  &param_cpu=STRing.SCANAndExtract("&parameters","CPU=","")
  &param_dualport=STRing.SCANAndExtract("&parameters","DUALPORT=","0")

  LOCAL &flashcodebase
  LOCAL &flashcodesize
  LOCAL &flashcodesectorsize
  LOCAL &flashdatabase
  LOCAL &flashdatasize
  LOCAL &flashdatasectorsize
  LOCAL &RAMbase
  LOCAL &RAMsize

; ------------------------------------------------------------------------------
; Setup CPU
  IF SYStem.MODE()<5
  (
    SYStem.RESet
    IF "&param_cpu"!=""
      SYStem.CPU &param_cpu
    ELSE
      SYStem.CPU TMPM3H*
    SYStem.Option EnReset OFF
    SYStem.Up
  )

  ; Disable watchdog
  Data.Set 0x400BB404 %Long 0x00000000   ; SIWD-EN disable timer
  Data.Set 0x400BB408 %Long 0x000000B1   ; SIWD-CR write key

; ------------------------------------------------------------------------------
; Setup flash configuration depending on selected CPU.
  IF CPUIS("TMPM3H*F10*")
  (
    &flashcodebase=0x00000000
    &flashcodesize=0x100000
    &flashcodesectorsize=0x1000
    &flashdatabase=0x30000000
    &flashdatasize=0x8000
    &flashdatasectorsize=0x1000
    &RAMbase=0x20000400
    &RAMsize=0x20000
  )
  ELSE
  (
    PRINT %ERROR "FLASH size of CPU type is unknown"
    ENDDO
  )

; --------------------------------------------------------------------------------
; Flash declaration
  FLASH.RESet
  GOSUB FlashDeclaration "&param_dualport"

  ; Flash script ends here if called with parameter PREPAREONLY
  IF &param_prepareonly
    ENDDO PREPAREDONE

; ------------------------------------------------------------------------------
; Flash programming example
  DIALOG.YESNO "Program flash memory?"
  LOCAL &progflash
  ENTRY &progflash
  IF &progflash 
  (
    FLASH.ReProgram.ALL /Erase
    Data.LOAD.auto *
    FLASH.ReProgram.off

    ; Reset device
    SYStem.Down
    SYStem.Up
  )
  ENDDO

; --------------------------------------------------------------------------------
; SUBROUTINES
; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU
;
;   Please do NOT modify the TRACE32 flash declaration.
;
;   Modifications can result in unpredictable behavior.
;   Please contact support@lauterbach.com for any changes.
FlashDeclaration:
  (
    PARAMETERS &param_dualport
    PRIVATE &FlashDriver

    IF CPUIS("TMPM3H*F10*")
    (
      &FlashDriver="tmpm3hxf10.bin"
      FLASH.Create 1. &flashcodebase++((&flashcodesize)-1) &flashcodesectorsize TARGET Long
      FLASH.Create 2. &flashdatabase++((&flashdatasize)-1) &flashdatasectorsize TARGET Long
    )

    IF (("&param_dualport"!="1")||SYStem.ACCESS.DENIED())
      FLASH.TARGET &RAMbase &RAMbase+0x1000 0x1000 ~~/demo/arm/flash/long/&FlashDriver
    ELSE
      FLASH.TARGET &RAMbase E:&RAMbase+0x1000 0x1000 ~~/demo/arm/flash/long/&FlashDriver /DualPort

    RETURN
  )