; --------------------------------------------------------------------------------
; @Title: SPI FLASH Program script for the RP2040 Raspberry Pi Pico
;
; @Description:
; The W25Q16 is connected to the SSI_0 controller
;
; SRAM: 0x20001000
; QuadSPI(controller) Base: 0x18000000
; QuadSPI Flash XIP Base: 0x10000000
;
;   Script arguments:
;
;    DO rp2040-spi [PREPAREONLY] [CPU=<cpu>] [DUALPORT=0|1]
;
;      PREPAREONLY only declares flash but does not execute flash programming
;
;      CPU=<cpu> selects CPU derivative <cpu>
;
;      DUALPORT=0|1 default value is 0 (disabled).
;
;   Example:
;
;   DO ~~/demo/arm/flash/rp2040-spi.cmm PREPAREONLY DUALPORT=1
;
; @Board: Raspberry Pi Pico
; @Chip: RP2040-CORE0
; @Author: JIM, ING, MPL
; @Keywords: ARM, Cortex-M0+, Flash
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: rp2040-spi.cmm 11387 2022-10-07 08:38:20Z jjeong $

ENTRY %LINE &parameters

PRIVATE &param_prepareonly &param_cpu &param_dualport
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
&param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")
&param_dualport=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"DUALPORT=","0")

&QSPI_BASE=0x18000000  ;SPI0 controller address

SYStem.Down
SYStem.CPU RP2040-CORE0
SYStem.CONFIG.DEBUGPORTTYPE SWD
SYStem.Option.DEBUGPORTOptions.SWITCHTOSWD.DormantToSwd

SYStem.Option.DUALPORT ON
SYStem.MemAccess DAP
SYStem.JtagClock CTCK 10MHz
SYStem.Up

; ------------------------------------------------------------------------------
; Cache Disable
Data.Set A:0x14000000 %LE %Long 0x0  ;XIP_CRTL_BASE

; ------------------------------------------------------------------------------
; Flash declaration
GOSUB FlashDeclaration "&param_dualport"

//Check the reset handler in the flash, to detect the empty flash or non bootable code in the flash
IF (Data.Long(A:0x10000104)&0xFFC00000)!=0x10000000
(
  &IO_QSPI_BASE=0x40018000

  //1.1 Use hard reset to force IO and pad controls to known state
  Data.Set 0x4000E000 %Long  0x240
  Data.Set 0x4000F000 %Long  0x240

  //1.2 then mux XIP block onto internal QSPI flash pads
  Data.Set &IO_QSPI_BASE+0x04 %Long 0x0
  Data.Set &IO_QSPI_BASE+0x0C %Long 0x0
  Data.Set &IO_QSPI_BASE+0x14 %Long 0x0
  Data.Set &IO_QSPI_BASE+0x1C %Long 0x0
  Data.Set &IO_QSPI_BASE+0x24 %Long 0x0
  Data.Set &IO_QSPI_BASE+0x2C %Long 0x0
)

; Verify FLASH Manufacturer and Device ID
SILENT.FLASH.SPI.CMD 1. 0x9F /READ 0x4 VM:0x0
IF (Data.Long(vm:0)&0xFFFFFF)!=0x1540EF //W25Q16 id code
(
  PRINT "We expect the id code 0x1540EF but we got the id 0x" %Hex Data.Long(vm:0x0)&0xFFFFFF
  FLASH.Delete 1.
  ENDDO
)

; Flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
  ENDDO PREPAREDONE

; -------------------------------------------------------------------------------
; Flash programming example
DIALOG.YESNO "Program flash memory?"
LOCAL &progflash
ENTRY &progflash
IF &progflash
(
  FLASH.ReProgram.ALL
  Data.LOAD.auto *
  ;Data.LOAD.Binary * 0x10000000
  FLASH.ReProgram.off

  ; Reset device
  PRINT "Please power-cycle the board after flash program is complete"
)
ENDDO

FlashDeclaration:
(
  PRIVATE &FlashSize &FlashDriver  &FlashBaseAddr
  PARAMETERS &DualPort

  FLASH.RESet

  &FlashDriver="snor3b_rp2040.bin"
  &FlashSize=0x200000        ;2Mbytes (16MBits)
  &FlashBaseAddr=0x10000000  ;SPI AHB base address

  FLASH.Create  &FlashBaseAddr++(&FlashSize-0x1)    0x10000   TARGET   Byte

  IF "&DualPort"=="0"
    FLASH.TARGET  0x20001000    0x20002000  0x2000  ~~/demo/arm/flash/byte/&FlashDriver
  ELSE
    FLASH.TARGET  0x20001000  E:0x20002000  0x2000  ~~/demo/arm/flash/byte/&FlashDriver  /DualPort

  FLASH.List

  RETURN
)