; --------------------------------------------------------------------------------
; @Title: Flash declaration for Nuvoton M471 internal flash
; @Description:
;   Script arguments:
;
;    DO m471 [PREPAREONLY] [CPU=<cpu>] [DUALPORT=0|1]
;
;      PREPAREONLY only declares flash but does not execute flash programming
;
;      CPU=<cpu> selects CPU derivative <cpu>
;
;      DUALPORT=0|1 default value is 0 (disabled).
;
;   Example:
;
;   DO ~~/demo/arm/flash/m471 CPU=M471KI8AE PREPAREONLY
;
;     CPU-Type        Flash size   DFlash size    SRAM size
;                       [Byte]       [Byte]        [Byte]
; --------------------------------------------------------------------------------
;    M471KI8AE         0x80000       0x8000       0x10000
;    M471VI8AE         0x80000       0x8000       0x10000
;    M471VG7AE         0x40000       0x8000       0x0C000
;    M471QI8AE         0x80000       0x8000       0x10000
;    M471QG7AE         0x40000       0x8000       0x0C000
;    M471R1E6AE        0x20000       0x0          0x08000
;    M471R1D6AE        0x10000       0x0          0x08000
;    M471SE6AE         0x20000       0x0          0x08000
;    M471SD6AE         0x10000       0x0          0x08000
;    M471MD6AE         0x10000       0x0          0x08000
;
; @Author: BWR
; @Chip: M471*AE
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Rev: 10516 $
; $Id: m471.cmm 10516 2022-02-02 11:39:30Z bschroefel $




PRIVATE &parameters
ENTRY %LINE &parameters

PRIVATE &param_prepareonly &param_cpu &param_dualport
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
&param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")
&param_dualport=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"DUALPORT=","0")

; ------------------------------------------------------------------------------
; Setup CPU

IF SYStem.MODE()<5
(
  SYStem.RESet

  IF "&param_cpu"!=""
    SYStem.CPU &param_cpu
  IF !CPUIS(M471*)
    SYStem.CPU M471*

  SYStem.CONFIG DEBUGPORTTYPE SWD

  SYStem.Up
)

; ------------------------------------------------------------------------------
; Flash declaration

FLASH.RESet
GOSUB FlashDeclaration "&param_dualport"

; Flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
  ENDDO PREPAREDONE

; -------------------------------------------------------------------------------
; Flash programming example

DIALOG.YESNO "Program flash memory?"
LOCAL &progflash
ENTRY &progflash
IF &progflash
(
  FLASH.ReProgram.ALL
  Data.LOAD.auto *
  FLASH.ReProgram.off

  ; Reset device
  SYStem.Down
  SYStem.Up
)

ENDDO


; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU

FlashDeclaration:
(
  PRIVATE &FlashSize &FlashDriver &DoubleBank
  PARAMETERS &DualPort

  IF CPUIS("M471*I*AE")
  (
    &FlashSize=0x80000
  )
  ELSE IF CPUIS("M471*G*AE")
  (
    &FlashSize=0x40000
  )
  ELSE IF CPUIS("M471*E*AE")
  (
    &FlashSize=0x20000
  )
  ELSE IF CPUIS("M471*D*AE")
  (
    &FlashSize=0x10000
  )
  ELSE
  (
    PRINT %ERROR "FLASH size of CPU type is unknown"
    ENDDO
  )

  &DoubleBank=TRUE()
  IF CPUIS("M471*")
  (
    &FlashDriver="m471.bin"
    &DoubleBank=TRUE()
  )
  ELSE
  (
    PRINT %ERROR "FLASH driver for CPU type is not defined"
    ENDDO
  )

  IF &DoubleBank
  (
    FLASH.Create 1. 0x00000000++(&FlashSize/2-1)  0x800 TARGET Long
    FLASH.Create 2. (&FlashSize/2)++(&FlashSize/2-1)  0x800 TARGET Long
  )
  ELSE IF !&DoubleBank
  (
    FLASH.Create 1. 0x00000000++(&FlashSize-1)  0x800 TARGET Long
  )
  
  IF "&DualPort"=="0"
    FLASH.TARGET 0x20000000 0x20001000 0x0800 ~~/demo/arm/flash/long/&FlashDriver
  ELSE
    FLASH.TARGET 0x20000000 EAHB:0x20001000 0x0800 ~~/demo/arm/flash/long/&FlashDriver /DualPort

  RETURN
)