; --------------------------------------------------------------------------------
; @Title: Freescale QorIQ LS1088A QSPI FLASH Programming Template
; @Description:
;   Example script to program a MT25QU128ABA (Micron) attached to CS#0 of a
;   LS1088A from NXP.
;
;   Internal SRAM: 0x18000000
;   QuadSPI(controller) Base: 0x20c0000
;   FLASH BASE ADDRESS(Qspi mapped): 0x20000000
;
;   Prerequisites for MicroSys SBC-LS1088A:
;    * Connect Debug Cable/Combiprobe to JTG0 Tagconnect using a custom adapter
;      ensure trace length is as short as possible
;    * set SW1[0..1]=0y00 => QSPI and ensure a valid RCW is programmed
;      or
;      set SW1[0..1]=0y11 => SD-Card and insert a SD-Card with valid RCW
;      for the SD-Card adapt the ResBreak/WaitReset block
;
; @Author: amerkle
; @Board: MicroSys SBC-LS1088A
; @Chip: LS1088A
; @Keywords:  MT25QU128ABA Flash SPI QuadSPI
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: ls1088-spi.cmm 11733 2023-01-16 08:55:12Z bschroefel $

LOCAL &parameters
ENTRY %LINE &parameters

LOCAL &param_prepareonly
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)

&QSPI_BASE=0x20c0000

RESet
SYStem.RESet
SYStem.CPU LS1088A
SYStem.MemAccess DAP
SYStem.Option TRST OFF
SYStem.Option EnReset ON
SYStem.Option MemStatusCheck ON
CORE.ASSIGN 1.
Trace.DISable
SYStem.Up

; fix-up core state - switch to EL3, endless loop @0x18000000, MMU-OFF
Data.Assemble 0x18000000 b $-0x0
Register.Set PC 0x18000000
Register.Set M 0x5 ;EL1h
GOSUB MMU_DISABLE
//Data.Set SPR:0x36100 %Long Data.Long(SPR:0x30100)&~0x1   ;for EL1

; init QSPI-Controller
Data.Set A:(&QSPI_BASE+0x000) %LE %Long 0xF000C              ; QSPI_MCR[END_CFG], 64LE
Data.Set A:(&QSPI_BASE+0x100) %LE %Long 0x20000000         ; SFAR   , Serial Flash A1 Base Address
Data.Set A:(&QSPI_BASE+0x180) %LE %Long 0x30000000         ; SFA1AD , Serial Flash A1 Top Address (QuadSPI_SFA1AD)

GOSUB READ_ID_TEST

LOCAL &pdd
&pdd=OS.PresentDemoDirectory()

//QSPI AHB(A:0x20000000) read configuration
IF TRUE()
(
  //3byte read at 0x20000000
  Data.Set AD:&QSPI_BASE+0x310 %LE %Long (0x08180400|0x3)
  Data.Set AD:&QSPI_BASE+0x314 %LE %Long 0x24001C08
)
ELSE
(
  //4byte read at 0x20000000
  Data.Set AD:&QSPI_BASE+0x310 %LE %Long (0x08200400|0x13)
  Data.Set AD:&QSPI_BASE+0x314 %LE %Long 0x24001C08
)


FLASH.RESet
FLASH.Create 0x20000000++0x00ffffff    0x40000   TARGET   Byte
FLASH.TARGET 0x18000000   0x18002000   0x1000   &pdd/flash/byte/snor3b_ls1088.bin

; Flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
    ENDDO PREPAREDONE

; -------------------------------------------------------------------------------
; Flash programming example
; -------------------------------------------------------------------------------

  DIALOG.YESNO "Program flash memory?"
  LOCAL &progflash
  ENTRY &progflash
  IF &progflash
  (
    FLASH.ReProgram.ALL
    Data.LOAD.auto *
   ;Data.LOAD.Binary * 0x20000000
    FLASH.ReProgram.off
  )

ENDDO

; --------------------------------------------------------------------------------

READ_ID_TEST:
(
  PRINT "READ_ID_TEST..."
  &temp=Data.Long(A:&QSPI_BASE)
  Data.Set A:&QSPI_BASE %Long %LE (&temp|0x0c00)   //clear Tx/Rx buffer

  Data.Set A:(&QSPI_BASE+0x300)  %Long %LE 0x5AF05AF0  ;  LUTKEY
  Data.Set A:(&QSPI_BASE+0x304)  %Long %LE 0x2  ;  LCKCR

  //SEQID 5
  Data.Set A:(&QSPI_BASE+0x360) %Long %LE 0x1c04049f   ; LUT0, SEQID0
  Data.Set A:(&QSPI_BASE+0x364)  %Long %LE 0x0
  Data.Set A:(&QSPI_BASE+0x368) %Long %LE 0x0
  Data.Set A:(&QSPI_BASE+0x36C)  %Long %LE 0x0

  // assert Read id command
  Data.Set A:(&QSPI_BASE+0x008) %Long %LE (5.<<24.)  ;    (5.<<24.)
  WAIT 100.ms

  &temp=Data.Long(A:&QSPI_BASE)
  Data.Set ZSD:&QSPI_BASE %Long %LE (&temp|0x0800)   //clear Tx buffer

  PRINT "1st 0x" (Data.Long(A:&QSPI_BASE+0x200)>>00.)&0xFF " (Manufacturer)"
  PRINT "2nd 0x" (Data.Long(A:&QSPI_BASE+0x200)>>08.)&0xFF " (Device ID)"
  PRINT "3rd 0x" (Data.Long(A:&QSPI_BASE+0x200)>>16.)&0xFF
  PRINT "4th 0x" (Data.Long(A:&QSPI_BASE+0x200)>>24.)&0xFF
  RETURN
)

MMU_DISABLE:

  LOCAL &sctlr &cpsr &sctlrAddr
 
  &cpsr=Register(cpsr)
  
  IF (&cpsr&0x10)==0x10
  (
    PRINTS "MMU off not supported for AArch32 in this test scenario"
    ENDDO
  )
  ELSE IF (&cpsr&0x0C)==0xC            // EL3h or EL3t
    &sctlrAddr=0x36100
  ELSE IF (&cpsr&0x0C)==0x8            // EL2h or EL2t
    &sctlrAddr=0x34100
  ELSE IF (&cpsr&0x0C)==0x4            // 0x5 ;EL1h or EL1t
    &sctlrAddr=0x30100
  ELSE
  (
    PRINTS "CPU mode unknown"
    ENDDO
  )
 
  &sctlr=Data.Quad(SPR:&sctlrAddr)
  
  &sctlr=&sctlr&0xFFFFFFFE
  
  Data.Set SPR:&sctlrAddr %Quad &sctlr
 
RETURN