; --------------------------------------------------------------------------------
; @Title: Script for programming of GigaDevice GD32W515 internal flash
;
; @Description: 
; Script arguments:
;
;  do gd32w515 [PREPAREONLY] [CPU=<cpu>]
;
;   PREPAREONLY only declares flash but does not execute flash programming example
;
;   CPU=<cpu> selects CPU derivative <cpu>
;
; List of GD32w515 derivatives and their configuration:
;
;   CPU-Type      Flash size   SRAM size
;                   (kByte)     (kByte)
; --------------------------------------------------------------------------------
;   GD32W515xG      1024.         384.
;   GD32W515xI      2048.         448.
; ------------------------------------------------------- -------------------------
;
; Flash base address is 0x08000000
; SRAM base address is  0x20000000
;
; @Author: ALI
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; @Chip: GD32w515*
; --------------------------------------------------------------------------------
; $Rev: 11230 $
; $Id: gd32w515.cmm 11230 2022-08-26 10:07:00Z alintner $

PRIVATE  &parameters
ENTRY %LINE &parameters

PRIVATE  &param_prepareonly
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)

PRIVATE  &param_cpu
&param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")

PRIVATE &param_dualport
&param_dualport=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"DUALPORT=","1")

; ------------------------------------------------------------------------------
; CPU setup

IF SYStem.MODE()<5
(
  SYStem.RESet
  IF "&param_cpu"!=""
    SYStem.CPU &param_cpu
  IF !CPUIS(GD32W515*)
    SYStem.CPU GD32W515*

    IF CABLE.TWOWIRE()
      SYStem.CONFIG.DEBUGPORTTYPE SWD

  SYStem.Up
)

; ------------------------------------------------------------------------------
; Flash declaration

FLASH.RESet

PRIVATE &FlashSize
GOSUB FlashDeclaration &param_dualport
ENTRY &FlashSize

; Flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
  ENDDO PREPAREDONE

; ------------------------------------------------------------------------------
; Flash programming example

DIALOG.YESNO "Program flash memory?"
PRIVATE  &progflash
ENTRY &progflash

IF &progflash 
(
  FLASH.ReProgram 0x08000000++(&FlashSize-1) /Erase
  Data.LOAD.auto *
  FLASH.ReProgram off

  ; Reset device
  SYStem.Down
  SYStem.Up
)

ENDDO


; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU 

FlashDeclaration:
(
  PRIVATE  &FlashSize &DualPort
  ENTRY &DualPort

  IF CPUIS("GD32W515?G*")
  (
    &FlashSize=0x100000 ; 1024 kByte
  )
  ELSE IF CPUIS("GD32W515?I*")
  (
    &FlashSize=0x200000 ; 2048 kByte
  )
  ELSE
  (
    PRINT %ERROR "FLASH size of CPU type is unknown"
    ENDDO
  )

  ; Program memory flash
  FLASH.Create 1. 0x08000000++(&FlashSize-1)  0x1000 TARGET Long

  IF "&DualPort"=="0"
  (
    FLASH.TARGET 0x20000000 0x20001000 0x400 ~~/demo/arm/flash/long/gd32w515.bin
  )
  ELSE
  (
    FLASH.TARGET 0x20000000 0x20001000 0x400 ~~/demo/arm/flash/long/gd32w515.bin /DualPort
  )

  RETURN &FlashSize
)