; --------------------------------------------------------------------------------
; @Title: Example for dialog with multiple check boxes
; @Description:
;   Shows a dialog with check boxes
;   For more information please refer to training_practice.pdf and ide_user.pdf
; @Keywords: checkbox, dialog, practice
; @Author: REI
; @Copyright: (C) 1989-2021 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: dialog_checkbox.cmm 20372 2023-02-01 14:27:35Z rweiss $


DIALOG
(
  HEADER "CHECKBOX Demo"
  POS 1. 0. 28. 1.
  TEXT "Options:"

  POS 1. 2. 10. 1.
  Option1: CHECKBOX "Option1" ""
  Option2: CHECKBOX "Option2" ""
  Option3: CHECKBOX "Option3" ""
  Option4: CHECKBOX "Option4" ""
  Option5: CHECKBOX "Option5" ""

  ;button "OK" (Default)
  POS 1. 9. 10. 1.
  DEFBUTTON "OK" "GOSUB OnOK"

  ;button "Uncheck"
  POS 17. 9. 10. 1.
  BUTTON "Uncheck" "GOSUB OnBtnClicked_UNCKECK"

  ;dialog open event
  INIT
  (
    ;make default settings
    DIALOG.DISABLE Option4
    DIALOG.DISABLE Option5
    DIALOG.SET Option1
    DIALOG.SET Option5
  )
  ;dialog close event
  CLOSE
  (
    ;same as OK button
    GOSUB OnOK
  )
  ;subroutines
  SUBROUTINE OnBtnClicked_UNCKECK
  (
    DIALOG.SET Option1 FALSE()
    DIALOG.SET Option2 FALSE()
    DIALOG.SET Option3 FALSE()
  )
  SUBROUTINE OnOK
  (
    LOCAL &Option1 &Option2 &Option3 &Option4 &Option5
    &Option1="not set"
    &Option2="not set"
    &Option3="not set"
    &Option4="not set"
    &Option5="not set"
    IF DIALOG.BOOLEAN(Option1)
      &Option1="set"
    IF DIALOG.BOOLEAN(Option2)
      &Option2="set"
    IF DIALOG.BOOLEAN(Option3)
      &Option3="set"
    IF DIALOG.BOOLEAN(Option4)
      &Option4="set"
    IF DIALOG.BOOLEAN(Option5)
      &Option5="set"

    ;close dialog window
    DIALOG.END

    ;print result
    DIALOG.OK "1:&Option1" "2:&Option2" "3:&Option3" "4:&Option4" "5:&Option5"
  )
)

ENDDO