; --------------------------------------------------------------------------------
; @Title: Example for an Automated Program Test by PRACTICE
; @Description:
;   The data file contains the HLL expressions to be checked
;   and the comparison to be made separated by a blank.
; @Keywords: area, hll, open, practice, read
; @Author: REI
; @Copyright: (C) 1989-2014 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: swtest.cmm 8581 2015-08-17 14:15:21Z wwbenayed $


SCREEN.ON
AREA.Create HLLLOG
AREA.Select HLLLOG

WinPOS ,,30.,10.
AREA HLLLOG

LOCAL &hllexp &hllcmp &filename &errors

&errors=0.
&filename="swtest.hll"

OPEN #1 &filename

PRINT "TEST FILE &filename"

WHILE 0x1==0x1
(
  READ #1 &hllexp &hllcmp
  IF "&hllexp"==""
    GOTO done

  PRINT " &hllexp&hllcmp"
  IF "&hllcmp"==""
  (
    Var &hllexp
    WAIT !STATE.RUN()
  )
  ELSE
  (
    IF Var.VALUE("&hllexp&hllcmp")==0
    (
      Var &hllexp
      PRINT "error calculating &hllexp&hllcmp"
      &errors=&errors+1.
    )
  )
)

done: 
  IF &errors>0x0
    PRINT &errors " ERROR(S)"
  ELSE
    PRINT "ALL TESTS PASSED"

  CLOSE #1

  ENDDO &errors