; --------------------------------------------------------------------------------
; @Title: Example Script for programming of ST GD32F4xx internal flash
;
; @Description:
;
; Script arguments:
;
;   DO gd32f4xx [PREPAREONLY] [CPU=<cpu>] [DUALPORT=0|1]
;
;     PREPAREONLY only declares flash but does not execute flash programming
;
;     CPU=<cpu> selects CPU derivative <cpu>
;
;     DUALPORT default value is 0 (disabled). If DualPort mode is enabled
;             flash algorithm stays running until flash programming is
;             finished. Data is tranferred via dual port memory access. 
;
; Example:
;
;   DO ~~/demo/arm/flash/gd32f4xx CPU=GD32F470ZK DUALPORT=1 PREPAREONLY
;
; List of GD32F4xx derivatives and their configuration:
;
;   CPU-Type      Flash size
;                   [kByte]
;   -------------------------
;   GD32F4xxxC         256.
;   GD32F4xxxE         512.
;   GD32F4xxxG        1024.
;   GD32F4xxxI        2048.
;   GD32F4xxxK        3072.
;
; Flash base address is 0x08000000
; SRAM base address is  0x20000000
;
; @Author: WRD
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; @Chip: GD32F4* 
; --------------------------------------------------------------------------------
; $Rev: 11191 $
; $Id: gd32f4xx.cmm 11191 2022-08-11 11:47:26Z alintner $

  LOCAL &parameters
  ENTRY %LINE &parameters

  LOCAL &param_prepareonly
  &param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)

  LOCAL &param_cpu
  &param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")

  LOCAL &param_dualport
  &param_dualport=0
  IF VERSION.BUILD.BASE()>=43441.
    &param_dualport=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"DUALPORT=","0")

  ; --------------------------------------------------------------------------------
  ; CPU setup

  IF SYStem.MODE()<5
  (
    SYStem.RESet

    IF "&param_cpu"!=""
      SYStem.CPU &param_cpu
    IF !CPUIS(GD32F4*)
        SYStem.CPU GD32F4*

    IF CABLE.TWOWIRE()
      SYStem.CONFIG.DEBUGPORTTYPE SWD

    SYStem.Up
  )

  ; --------------------------------------------------------------------------------
  ; Flash declaration

  FLASH.RESet
  GOSUB FlashDeclaration &param_dualport

  ; Flash script ends here if called with parameter PREPAREONLY
  IF &param_prepareonly
    ENDDO PREPAREDONE

  ; --------------------------------------------------------------------------------
  ; Flash programming example

  DIALOG.YESNO "Program flash memory?"
  LOCAL &progflash
  ENTRY &progflash

  IF &progflash 
  (
    FLASH.ReProgram.ALL /Erase
    Data.LOAD.auto *
    FLASH.ReProgram.off

    ; Reset device
    SYStem.Down
    SYStem.Up
  )

  ENDDO


; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU 

FlashDeclaration:
  LOCAL &DualPort
  ENTRY &DualPort

  LOCAL &FlashSize &FlashDriver
  &FlashDriver="gd32f4xx.bin"

  IF CPUIS("GD32F403*")
  (
    PRINT %WARNING "Flash programming for GD32F403* is not supported, yet"
    ; a different &FlashDriver=gd32f403.bin would be needed here.
    ENDDO
  )

  IF CPUIS("GD32F4???C") ; 256k
  (
    &FlashSize=0x40000
  )
  ELSE IF CPUIS("GD32F4???E") ; 512k
  (
    &FlashSize=0x80000
  )
  ELSE IF CPUIS("GD32F4???G") ; 1024k
  (
    &FlashSize=0x100000
  )
  ELSE IF CPUIS("GD32F4???I") ; 2048k
  (
    &FlashSize=0x200000
  )
  ELSE IF CPUIS("GD32F4???K") ; 3072k
  (
    &FlashSize=0x300000
  )
  ELSE
  (
    PRINT %ERROR "FLASH size of CPU type is unknown"
    ENDDO
  )

  PRIVATE &offset &size &index
  &offset=0.
  &index=0.

  WHILE (&offset<&FlashSize)
  (
    IF CPUIS("GD32F403")
    (
      IF (&index<256.)
        &size=0x800 ; 2k sector
      ELSE
        &size=0x1000 ; 2k sector
    )
    ELSE
    (
      IF (&index<4.)||((&index>=12.)&&(&index<16.))
        &size=0x4000 ; 16k sector
      ELSE IF (&index==4.)||(&index==16.)
        &size=0x10000 ; 64k sector
      ELSE IF (&index<24.)
        &size=0x20000 ; 128k sector
      ELSE
        &size=0x40000 ; 256k sector
    )

    FLASH.Create 1. (0x08000000+&offset)++(&size-1) TARGET Byte &index
    &offset=&offset+&size
    &index=&index+1.
  )

  ; For Main Flash memory boot mode flash memory is aliased to address 0x0
  ; Because SYSCFG_MEMRMP:MEM_MODE[1:0] is not indicating active memory remap
  ; we are comparing flash reset vector against reset vector at alias address
  SILENT.Data.ComPare 0x0--0x7 0x08000000
  IF !FOUND()
    FLASH.CreateALIAS 0x00000000--0x001FFFFF 0x08000000

  IF &DualPort==0
    FLASH.TARGET 0x20000000 0x20001000 0x4000 ~~/demo/arm/flash/byte/&FlashDriver
  ELSE
    FLASH.TARGET 0x20000000 EAHB:0x20001000 0x4000 ~~/demo/arm/flash/byte/&FlashDriver /DualPort

  RETURN