; --------------------------------------------------------------------------------
; @Title: RUST demo for STM32F756ZG (FLASH)
; @Description:
;   Programs the rust demo application into the processor internal flash and
;   sets up a demo debug scenario.
;   Prerequisites:
;    * Connect Debug Cable to CN15 JTAG
;      or
;      Connect Combiprobe/uTrace to CN12 TRACE
; @Keywords: ARM, Cortex-M7, Flash, RUST
; @Author: AME
; @Board: STM32756G-EVAL2, Simulator
; @Chip: STM32F7*
; @Copyright: (C) 1989-2024 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: start-stm32f756.cmm 22690 2024-04-24 14:35:30Z amerkle $


WinCLEAR

; --------------------------------------------------------------------------------
; initialize and start the debugger
RESet
SYStem.RESet
SYStem.CPU STM32F756ZG
SYStem.CONFIG.DEBUGPORTTYPE SWD
IF COMBIPROBE()||UTRACE()
(
  SYStem.CONFIG.CONNECTOR MIPI20T
)
SYStem.Option DUALPORT ON
SYStem.MemAccess DAP
SYStem.JtagClock 10MHz
Trace.DISable
SYStem.Up

; ------------------------------------------------------------------------------
; Flash programming
; prepare flash programming (declarations)
DO ~~/demo/arm/flash/stm32f7xx PREPAREONLY

; ReProgram Flash
FLASH.ReProgram ALL
Data.LOAD.Elf "~~~~/rust_flash_thumb_ii_v7m.elf" /RelPATH
FLASH.ReProgram OFF

; --------------------------------------------------------------------------------
; Reset the target again
SYStem.Up

; --------------------------------------------------------------------------------
; start program execution
Go first_arm_demo::__cortex_m_rt_main::*
WAIT !STATE.RUN()

; --------------------------------------------------------------------------------
; open some windows
WinCLEAR
Mode.Hll
WinPOS 0. 0.
List.auto
WinPOS 120. 0. 100. 8.
Frame.view
WinPOS 120. 14.
Var.Watch %SpotLight
Var.AddWatch ast flags
WinPOS 120. 25.
Register.view /SpotLight
WinPOS 0. 32.
Var.DRAW %DEFault SINEWAVE

ENDDO