; --------------------------------------------------------------------------------
; @Title: This script prints the content of a large TRACE32 window
; @Description:
;
;   TRACE32 offers the ability to write data to files using commands such as
;   Var.WRITE or WinPrint.
;   However, when TRACE32 window is large, the output is limited.
;   This script will help to increase this limit.
;
;   To make sure that the generated file contains all the data, check the TRACE32
;   window after executing this script. 
;   If this windows doesn't scroll until the end, increase the value of &n.
;
;   Script arguments:
;   DO vertical_display.cmm [FILENAME="filename.txt"] [CMD="your cmd"]
;
;      FILENAME  must be an empty text file.
;      CMD is the command that opens the wanted window.
;
;   Example:
;   DO vertical_display.cmm FILENAME="vertical_display.txt" \
;       CMD="Var.View %Hex %open BigArray"
;
; @Keywords: Var.WRITE, WinPrint, WinPAN, WINPRT
; @Author: NEZ
; @Copyright: (C) 1989-2019 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: vertical_display.cmm 14880 2019-09-03 14:36:56Z nzouari $

;get parameters
LOCAL &param
ENTRY %LINE &param

&filename=STRing.SCANAndExtract("&param","FILENAME=","")
&filename=&filename

&cmd=STRing.SCANAndExtract("&param","CMD=","")
; convert string to command
&cmd=&cmd

GLOBAL &winSize &n

&winSize = 50.  ;is the size of The TRACE32 Window
                ;can be changed
                ;make sure that this size doesn't exceed the width of your screen

&n = 100.       ;change this value as needed.

PRINTER.FILE &filename /APPEND 
WinPOS  ,  ,  , &winSize ,  ,  , myWin 
&cmd
WinPAN 0. 0. ;this command is used to scroll or pan a window
SCREEN.WAIT  ;necessary to update the screen after WINPAN if executing 
             ;within a PRACTICE script
WINPRT myWin

REPEAT &n
(
  WinPAN 0. ,&winSize
  SCREEN.WAIT
  WINPRT myWin
)