; --------------------------------------------------------------------------------
; @Title: Freescale QorIQ LS1043A Reference Design Board SD Card Programming Script
; @Description:
; SD Card is connected to eSDHC
;
; The RCW_SRC field (SDHC_BASE, 371 bits) should be 0y0 ,
; The RCW_SRC field (SDHC_EXT, 363-365 bits) also be 0y000
;
; Internal SRAM    : 0x1000_1000
; eSDHC base : 0x156_0000
;
; @Author: jjeong
; @Copyright: (C) 1989-2022 Lauterbach GmbH, licensed for use with TRACE32(R) only
; @Chip: LS1043A
; @Keywords: Flash SDHC
; --------------------------------------------------------------------------------
; $Id: ls1043-sd.cmm 10516 2022-02-02 11:39:30Z bschroefel $

&MMC_BASE=0x1560000

SYStem.Down
SYStem.CPU LS1043A
SYStem.Option HRCWOVerRide OFF
SYStem.MemAccess DAP
SYStem.Option TRST OFF
SYStem.Option EnReset ON
CORE.ASSIGN 1.

ETM.OFF
SYStem.Up

Register.Set M 0x5 ;EL1h

MAP.BE &MMC_BASE++0xFFFF

; --------------------------------------------------------------------------------
; Config SDHC
; --------------------------------------------------------------------------------
Data.Set A:&MMC_BASE+0x04 %BE %Long 0x00010200  ; blk size,cnt
Data.Set A:&MMC_BASE+0x28 %BE %Long 0x08800020  ; bus width, endian
Data.Set A:&MMC_BASE+0x2C %BE %Long 0x008E8088  ; 400KHz clk
Data.Set A:&MMC_BASE+0x34 %BE %Long 0x00000033  ; BRR,BWR, TCI, CCI interrupt enable
Data.Set A:&MMC_BASE+0x44 %BE %Long 0x00100010  ;read/write fifo threshold level 64bytes

GOSUB READ_ID_TEST

LOCAL &pdd
&pdd=OS.PresentDemoDirectory()

Break.RESet

FLASHFILE.RESet

;FLASHFILE.CONFIG  <eSDHC controller> <0x0>  <0x0>
FLASHFILE.CONFIG  &MMC_BASE         0x0  0x0

; FLASHFILE.TARGET <code_range>       <data_range>       <algorithm file>
FLASHFILE.TARGET 0x10001000++0x2FFF   0x10005000++0x3FFF    &pdd/flash/byte/emmcsd_ls10xx.bin  /KEEP  /STACKSIZE 0x200

Data.Set A:&MMC_BASE+0x2C %BE %Long 0x008E8088  ; 400KHz clk

FLASHFILE.GETID

Data.Set A:0x1560000+0x2C %BE %Long 0x008E0228  ; increase mmc clk

FLASHFILE.DUMP 0x0   ; Read Flash

;FLASHFILE.ERASE 0x0--0xFFFFF    ; Erase Flash
;FLASHFILE.LOAD * 0x0            ; Write Flash

ENDDO


READ_ID_TEST:
//SD(HC) interface, not MMC
//CMD0
RePeaT 2.
(
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long 0x0  ;arg 
Data.Set &MMC_BASE+0xc %Long 0x0  ;cmd
WAIT 100.ms
)

//CMD8, is madatory to intialize High Capacity SD Memory Card
RePeaT 2.
(
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long 0x1AA     ;arg
Data.Set &MMC_BASE+0xc %Long 0x08020000 ;cmd
WAIT 100.ms

&status=Data.Long(A:&MMC_BASE+0x30)
IF (&status&0x30000)==0x0
(
PRINT "passed CMD8(voltage check)"
GOTO jump_cmd55
)
ELSE
(
//CMD0
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long 0x0  ;arg 
Data.Set &MMC_BASE+0xc %Long 0x0  ;cmd
WAIT 100.ms
)
)

jump_cmd55:
//CMD55
RePeaT 10.
(
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long 0x0 ;arg
Data.Set &MMC_BASE+0xc %Long 0x37020000 ;cmd55, resp1
WAIT 100.ms

//ACMD41
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long 0x40FF8000 ;arg
Data.Set &MMC_BASE+0xc %Long 0x29020000 ;cmd41, resp1
WAIT 100.ms

&resp=Data.Long(A:(&MMC_BASE+0x10))
//print "CMD1 resp: 0x" &resp
IF (&resp&0x80000000)==0x80000000
(
GOTO jump_cmd2
)
)

PRINT "CMD1 fail"
END

jump_cmd2:
//CMD2
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long 0x0     ;arg
Data.Set &MMC_BASE+0xc %Long 0x02010000 ;cmd2
WAIT 10.ms

//CMD3
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long 0x00010000  ; arg, MMC RCA is (0x0001<<16.)
Data.Set &MMC_BASE+0xc %Long 0x03020000  ;cmd3
WAIT 10.ms

&cardaddress=Data.Long(A:(&MMC_BASE+0x10))
&cardaddress=&cardaddress&0xFFFF0000


//CMD10
Data.Set &MMC_BASE+0x30 %Long 0xFFFFFFFF ;clear status
Data.Set &MMC_BASE+0x8 %Long &cardaddress  ; arg, card address
Data.Set &MMC_BASE+0xc %Long 0x0A010000  ;cmd10
WAIT 10.ms

//Response2
PRINT "CID register"
PRINT "[127:104] 0x" Data.Long(A:(&MMC_BASE+0x1c))
PRINT "[103:72]  0x" Data.Long(A:(&MMC_BASE+0x18))
PRINT "[71:40]   0x" Data.Long(A:(&MMC_BASE+0x14))
PRINT "[39:8]    0x" Data.Long(A:(&MMC_BASE+0x10))

RETURN